Моделирование в Maya

ZVUKARb · 20 Февраля 2009

Всё что связано с Autodesk Maya обсуждаем здесь

========================================================

(составлено

break):

В: Где скачать обновления Майи?
О: На оф. сайте Autodesk: http://usa.autodesk.com/adsk/servlet/ps/dl/index?siteID=123112&id=2334435&linkID=9242259
----
В: Где взять плагины для работы со Сталкер-форматами?
О: Официальные для ТЧ - здесь: http://stalkerin.gameru.net/modules.php?name=Downloads&d_op=viewtheoned&lid=437
Официальные для ЧН/ЗП - здесь: http://stalkerin.gameru.net/modules.php?name=Downloads&d_op=viewtheoned&lid=436
Плагин bardak'а здесь: http://stalkerin.gameru.net/modules.php?name=Downloads&d_op=viewtheoned&lid=454
Обновляемые плагины для последних версий Maya лежат (2014) здесь.
----
В: Как установить плагины?
О: Официальные:
1) Скопировать xrayMaya_export.dll и xrayMaya_material.dll в $MAYA/bin/plug-ins
2) Скопировать BugTrap.dll и xray_path.ltx в $MAYA/bin
Бардаковские:
0) Смотри readme
----
В: Чем отличаются "официальные" плагины от плагина бардака?
О: Официальные плагины разработаны GSC. Могут экспортировать геометрию, скелетную анимацию (.skl) и
анимацию камеры (.anm). Импортера нет. Есть сборки до Maya 2010 включительно, но только под win32.
В комплекте с ними идет набор MEL-скриптов:
1) AEXRayMtlTemplate.mel создает дополнительные контролы для ноды XRayMtl в редакторе атрибутов.
Без него вы не увидите свитка hardware texturing и назначенная в color текстура останется "размытой".
2) exportXRayCameramоtionAdvance.mel - множественный экспорт анимации камеры (.anm)
3) exportXRayObjectAdvance.mel - множественный экспорт статических объектов (.object)
4) exportXRaySkinMotionAdvance.mel - массовый экспорт скелетной анимации (.skl)
5) exportXRaySkinObjectAdvance.mel - массовый экспорт скелетных объектов (.object)
6) XRayShaders.mel - менюшка для назначения engine/compiler shader'ов и game material'ов.
Часть этих скриптов вызывает функции пысовского экспортера и бесполезна для бардаковского плага.

Плагин бардака поддерживает импорт .ogf, .dm, .object, .omf, .skl, .skls и экспорт .object, .skl.
Экспортера .anm нет. Сборки под Maya 8.5-2014, включая x64 версии. Совместим с официальными плагинами
и XRay-материалом. Исходный код полностью открыт: https://bitbucket.org/stalker/xray_re-tools/src
(Квалифицированные кодеры - давайте конпелировать в месте!)
При всех достоинствах бардаковского плагина, имеются и недоработки:
1) нерешенная проблема со сглаживанием .object'ов формата ЗП
2) отсутствие экспорта анимации камеры в формат .anm
3) невозможно экспортировать клипы из TraX Editor'а
----
В: Я максист, хде xform в Майе?
О: Modify->freeze transforms, reset transforms

xr_startup_scene_init.mel
Устанавливает рабочие единицы и плоскости отсечки под Сталкера.

global proc xr_startup_scene_init() {
///
// Установка рабочих единиц
//
currentUnit -linear "meter" -time "ntsc";
///
// Установка плоскостей отсечки
//
viewClipPlane -nearClipPlane 0.01 -farClipPlane 1000 perspShape;
viewClipPlane -nearClipPlane 0.01 -farClipPlane 1000 topShape;
viewClipPlane -nearClipPlane 0.01 -farClipPlane 1000 frontShape;
viewClipPlane -nearClipPlane 0.01 -farClipPlane 1000 sideShape;print "XRay settings: initialized\n";xr_startup_plugin_loader();
}

xr_startup_plugin_loader.mel
Загружает и добавляет в автозагрузку xrayMayaTools.mll. Если версия Maya <= 2010, то дополнительно
пытается загрузить и убрать из автозагрузки xrayMaya_export.mll, а также выгрузить и убрать из
автозагрузки xrayMaya_material.mll (как рекомендовал bardak).

global proc xr_startup_plugin_loader() {
string $xray_maya_tools_path = `getenv MAYA_LOCATION`
         + "/bin/plug-ins/xrayMayaTools.mll";
string $xray_maya_material_path = `getenv MAYA_LOCATION`
         + "/bin/plug-ins/xrayMaya_material.mll";
string $xray_maya_export_path = `getenv MAYA_LOCATION`
         + "/bin/plug-ins/xrayMaya_export.mll";
///
// XRay Maya tools
//
if (!(`filetest -s $xray_maya_tools_path`)) {
  print "xrayMayaTools: plug-in not found\n";
} else if (`pluginInfo -q -loaded xrayMayaTools`) {
  print "xrayMayaTools: already loaded\n";
} else {
  loadPlugin xrayMayaTools;
  pluginInfo -e -autoload true xrayMayaTools;
  print ((`pluginInfo -q -loaded xrayMayaTools`)
    ? "xrayMayaTools: loaded\n"
    : "xrayMayaTools: not loaded\n");
}
///
// Официальные плагины
//
if (`about -apiVersion` <= 201000) {
  ///
  // Принудительная выгрузка material-плагина во избежание конфликта с xrayMayaTools
  //
  if (!(`filetest -s $xray_maya_material_path`)) {
   print "xrayMaya_material: plug-in not found, it's OK\n";
  } else if (`pluginInfo -q -loaded xrayMaya_material`) {
   unloadPlugin -force xrayMaya_material;
   pluginInfo -e -autoload false xrayMaya_material;
   print "xrayMaya_material: successfully unloaded\n";
  }
  ///
  // Загрузка экспортера
  //
  if (!(`filetest -s $xray_maya_export_path`)) {
   print "xrayMaya_export: plug-in not found\n";
  } else if (`pluginInfo -q -loaded xrayMaya_export`) {
   print "xrayMaya_export: already loaded\n";
  } else {
   loadPlugin xrayMaya_export;
   // убираем из автозагрузки во избежание конфликта
   pluginInfo -e -autoload false xrayMaya_export;
   print ((`pluginInfo -q -loaded xrayMaya_export`)
     ? "xrayMaya_export: loaded\n"
     : "xrayMaya_export: not loaded\n");
  }
}
print "XRay plug-ins: successfully loaded\n";
}

xr_object_export.mel
Переписанный ПЫСовский скрипт для множественного экспорта объектов. Для 2012 и выше.

global proc xr_object_export() {
if (size(`ls -sl`) == 0) {
  confirmDialog -title "Error"
     -message "Nothing selected!"
     -button "OK" -defaultButton "OK"
     -icon "warning";
  error "Nothing selected";
}
$response = `confirmDialog -title "Confirm action"
       -message "Are you sure to export all selected objects?"
       -button "Yes" -button "No" -defaultButton "Yes"
       -cancelButton "No" -dismissString "No"
       -icon "question"`;
if ($response == "Yes") {
  string $exported_objects[] = `ls -sl`;
  print ("Selected: \n");
  print $exported_objects;
  print "\n";
  print ("Export:\n");
  int $i = 0;
  string $export_dir[] = `fileDialog2 -caption "Export selection"
           -fileMode 3
           -okCaption "OK"
           -cancelCaption "Cancel"`;
  if ($export_dir[0] == "") {
   error "Export canceled\n";
  } else if ($export_dir[0] != "Cancel") {
   for ($i; $i < size($exported_objects); $i++) {
    select $exported_objects[$i];
    //polyTriangulate -name $exported_objects;
    string $name = $export_dir[0] + "/" + $exported_objects[$i];
    file -exportSelected -type "X-Ray object" $name;
    print ($name + ".object\n");
   }
  }
  print ("Summary: " + size($exported_objects) + " file(s) exported" + "\n");
  // FIXME: undo
} else if ($response == "No") {
  error "Export canceled\n";
}
}

AEXRayMtlTemplate.mel
О нем вы читали выше.

//AEXRayMtlTemplate.melglobal proc AEXRayMtlTemplate( string $nodeName ) {
AEswatchDisplay $nodeName;
editorTemplate -beginScrollLayout;editorTemplate -beginLayout "Common Material Attributes" -cl off;
  editorTemplate -addControl "color";
  editorTemplate -addControl "transparency";
  editorTemplate -addControl "incandescence";
editorTemplate -endLayout;editorTemplate -beginLayout "Hardware Texturing" -cl off;
AEhardwareTextureTemplate $nodeName
  ("color transparency incandescence");
editorTemplate -endLayout;editorTemplate -beginLayout "X-Ray Material Attributes" -cl off;
  editorTemplate -addControl "xrayDoubleSide";
  editorTemplate -addControl "xrayEngineShader";
  editorTemplate -addControl "xrayCompilerShader";
  editorTemplate -addControl "xrayGameMaterial";
editorTemplate -endLayout;editorTemplate -addExtraControls;
editorTemplate -endScrollLayout;
}

Поправленный скрипт Страховида - boolean и деформер полигональной поверхности (http://www.amk-team.ru/forum/index.php?showtopic=5422&p=734386)

global proc strah_deform_n_cut() {string $dfc_window = `window -title "Strahovid" -menuBar true`;menu -label "Edit";
  menuItem -label "Undo" -command "Undo";
  menuItem -label "Redo" -command "Redo";
columnLayout;menu -label "Help" -helpMenu true;
  menuItem -label "Discussion"
    -command "showHelp -absolute \"http:\/\/www.amk-team.ru\/forum\/index.php?showtopic=5422\""
    ;
columnLayout;scrollLayout scrollLayout;
  columnLayout -adjustableColumn true;
   frameLayout -label "Deform & cut tool" -borderStyle "in";
    columnLayout -adjustableColumn true;
     floatSliderGrp -label "Vertex offset X: "
         -field 1 -value 0.1 -min 0 -max 0.5 -step 0.01 X;
     floatSliderGrp -label "Vertex offset Y: "
         -field 1 -value 0.1 -min 0 -max 0.5 -step 0.01 Y;
     floatSliderGrp -label "Vertex offset Z: "
         -field 1 -value 0.1 -min 0 -max 0.5 -step 0.01 Z;
    setParent ..;    columnLayout -adjustableColumn true;
     button -w 174 -h 26 -label "Deform" -command "dfc_deform";
     button -w 174 -h 26 -label "Cut" -command "dfc_cut";
     button -w 174 -h 26 -label "Close" -command ("deleteUI -window " + $dfc_window);
    setParent ..;showWindow $dfc_window;
}//////////////////////////////////////////////////////////////////////////
proc dfc_deform() {
string $list[] = `ls -sl -fl`;
string $item;
float $mX = `floatSliderGrp -q -v X`;
float $mY = `floatSliderGrp -q -v Y`;
float $mZ = `floatSliderGrp -q -v Z`;
for($item in $list) {
  move -r (rand(-$mX,$mX)) (rand(-$mY,$mY)) (rand(-$mZ,$mZ)) $item;
}
}//////////////////////////////////////////////////////////////////////////
proc dfc_cut() {
string $o1[] = `ls -sl`;
string $ob1 = $o1[0];
string $ob2 = $o1[1];
string $o2[] = `duplicate $o1`;
string $o5[] = `duplicate $ob1`;
string $ob3 = $o2[0];
string $ob4 = $o2[1];
polyNormal $ob3;
string $rez1[] = `polyBoolOp -op 3 $ob1 $ob2`;
string $rez2[] = `polyBoolOp -op 3 $ob3 $ob4`;
xform -cp $rez1 $rez2 $o5;
select $o5;
}

xr_tools.mel
Меню для вызова вышеуказанных скриптов.

global proc xr_tools() {global string $gMainWindow;
setParent $gMainWindow;menu -l "X-Ray Tools" -p MayaWindow -tearOff true xr_tools;menuItem -label "Apply XRay settings"
   -annotation "Apply XRay settings"
   -command "xr_startup_scene_init"
   xr_startup_scene_init;menuItem -divider true;menuItem -label "Multiple export"
   -subMenu true
   -tearOff true
   ;menuItem -label "Export objects"
   -annotation "Export selected objects"
   -command "xr_object_export"
   xr_object_export;setParent -m ..;//////////////////////////////////////////////////////////////////////////
menuItem -label "XRay material..."
   -subMenu true
   -tearOff true
   ;
menuItem -divider true;////
// Удаление неиспользуемых Shading nodes. Сюда вынесено лишь для удобства.
//
menuItem -label "Delete unused shading nodes"
   -command "MLdeleteUnused"
   MLdeleteUnused;setParent -m ..;///////////////////////////////////////////////////////
menuItem -divider true;menuItem -label "About..."
   -subMenu true
   ;menuItem -label "Discussion"
   -command "showHelp -absolute \"http:\/\/www.amk-team.ru\/forum\/index.php?showtopic=5422\""
   ;   setParent -m ..;
}

userSetup.mel
Пользовательские установки. Здесь - подгрузка скриптов.

///
// Инициализация UI
//
evalDeferred -lowestPriority xr_tools;
///
// xr_startup_scene_init.mel выполняется каждый раз при создании новой сцены,
// в т.ч. сразу после загрузки Maya. Раскомментируйте, если нужно.
//
//scriptJob -event NewSceneOpened xr_startup_scene_init;

http://rusfolder.com/37228626

Ссылка на актуальную версию скрипта XrayToolMaya

В: Как правильно сообщать об ошибках?
О: 1) Сообщите версию Майи и используемых плагинов.
2) Подробно опишите свои действия и цель этих действий.
3) Приведите лог из окна вывода (output window) и редактора скриптов (script editor).
4) В тяжелых случаях не помещает выложить сцену.
----
В: Пытаюсь экспортировать скелетную анимацию пысовским плагом, но он выдает ошибку:
XR-Error: Can't export animation with FPS!=30.f
XR-Error: Export failed.
О: В XRay принята частота 30 кадров в секунду. Измените настройки: http://images.gameru.net/image/direct/401a3efaa2.png

Изменено 26 Сентября 2016 пользователем vadyan

break · 30 Сентября 2012

Говорил же - приведи лог из окна вывода, сразу бы все прояснилось.

Библиотеки были в патче, патч на сталкерине.

Страховид · 5 Октября 2012

В продолжение темы "текстуринга".

Думал сегодня как облегчить себе жизнь. И надумал следующее.

Простенькое окошечко гуи, на кнопки подвешена Планар_Маппинг с разными настройками проецирования, как то, откамеры или по осям.

window -t "Strahovid_Mapping" DROP_WINDOW;
columnLayout;

gridLayout -numberOfColumns 4 -cellWidthHeight 90 30;

button -l "Camera" -w 64 -c "camera";
button -l "X" -w 64 -c "x";
button -l "Y" -w 64 -c "y";
button -l "Z" -w 64 -c "z";

setParent..;
showWindow DROP_WINDOW;

global proc camera()
{
//string $list[] = `ls -sl`;
string $list[] = `ls -sl -fl`;
polyProjection -ch 1 -type Planar -ibd on -kir -md c $list;

}

global proc x()
{
string $list[] = `ls -sl -fl`;
polyProjection -ch 1 -type Planar -ibd on -kir -md x $list;
}

global proc y()
{
string $list[] = `ls -sl -fl`;
polyProjection -ch 1 -type Planar -ibd on -kir -md y $list;
}

global proc z()
{
string $list[] = `ls -sl -fl`;
polyProjection -ch 1 -type Planar -ibd on -kir -md z $list;
}

Страховид · 5 Октября 2012

Буду ещё вентелировать вопрос. В идеале хочу сделать скрипт, чтобы планар маппинг проецировался по нормали полигона, не зависимо куда она, нормаль, смотрит. При текстурировании лоуполи этот скрипт стал бы не заменим.

Страховид · 6 Октября 2012

Зацените ка ещё один скрипт. На одном сайте помогли разобраться. В результате - полезная весчь

Разрезание плоскостью. При выборе необходимо соблюдать последовательность, сначала плоскость, затем разрезаемый объект.

string $objs[] = `ls -sl`;
string $obj1 = $objs[0];
string $obj2 = $objs[1];

string $objss[] = `duplicate $objs`;
string $obj11 = $objss[0];
string $obj22 = $objss[1];

polyNormal -normalMode 0 -userNormalMode 0 -ch 1 $obj11;

polyBoolOp -op 3 -ch 1 -useThresholds 1 -preserveColor 0 $obj1 $obj2;
polyBoolOp -op 3 -ch 1 -useThresholds 1 -preserveColor 0 $obj11 $obj22;

В дополнение, скрин, объясняющий работу скрипта.

В дальнейших планах: сделать ГУИ, в нём объединить деформер с настраеваемым диапозоном рандрма (чтобы красиво корявить плоскость, см. скрин), сам скрипт кут, ну и может быть оффсет добавлю.

Страховид · 7 Октября 2012

Объединил несколько скриптов. Деформер - выделить вертексы, использовать скрипт. И разрезание объекта плоскостью (ровной или деформированной).

window -t "Strahovid_CUT" DROP_WINDOW;
columnLayout;
gridLayout -numberOfColumns 2 -cellWidthHeight 60 40;
button -l "DEFORM" -w 64 -c "def";
button -l "Undo" -w 64 -c "Undo;";
setParent..;
gridLayout -numberOfColumns 2 -cellWidthHeight 60 40;
button -l "CUT" -w 64 -c "cut";
button -l "Undo" -w 64 -c "Undo;";
setParent..;
showWindow DROP_WINDOW;
global proc cut()
{
string $o1[] = `ls -sl`; //создаём переменную
string $ob1 = $o1[0]; //раскладываем по индексам, последовательность выделения
string $ob2 = $o1[1];
string $o2[] = `duplicate $o1`; //дублируем переменную $o1, заносим результат в другую переменную
string $ob3 = $o2[0];
string $ob4 = $o2[1];
polyNormal $ob3; //делаем реверс нормалей полученного объекта (плоскости)
string $rez1[] = `polyBoolOp -op 3 $ob1 $ob2`; //применяем булеан, заносим результаты в переменные
string $rez2[] = `polyBoolOp -op 3 $ob3 $ob4`;
xform -cp $rez1; //центрируем пивоты у полученных объектов
xform -cp $rez2;
}
global proc def()
{
string $list[] = `ls -sl -fl`;
string $item;
for($item in $list)
{
move -r (rand(-0.1,0.1)) (rand(-0.1,0.1)) (rand(-0.1,0.1)) $item; //двигает вершины рандомно, в заданных диапазонах
}
}

Кстати, в качестве "режущего" можно использовать также и сферы и кыбики и прочий как примитив, так более сложную геометрию. Поэкспериментируйте, интересные возможности для реализации чего-нибудь открываются

Изменено 7 Октября 2012 пользователем Страховид

mwesten1 · 7 Октября 2012

вещ полезная .

Я вот чо хотел спросить:

В максе можно разделить обьект на eлементы и затекстурировать их разными текстурами и в конце получится терейн с мульти текстурами и одним обьектом. А вот в мая нужно разделять дорогу и терейн и текстурировать их по отдельности а потом соединять или можно както по другому? Просто новичок в мая

Пиши грамотней. Cyclone

break · 7 Октября 2012

Страховид

Все это, конечно, замечательно, но стандартных булевых операций никто не отменял если неохота пользоваться контекстым меню, то можно вынести три кнопки на отдельную менюшку, но остальное - изобретение велосипеда. Деформировать объекты удобнее sculpt geometry tool'ом.

http://img267.imageshack.us/img267/8545/81240241.jpg

ЗЫ код глючноват

ЗЫЫ во вьюпорте беда с клиппингом, видно сетку с задних поверхностей

mwesten1

Выделить нужные полигоны, потом через контекстное меню (Shift+ПКМ) Extract faces

Соединить - то же самое, но команда Combine.

Разбить объект на исходные mesh'и - Separate.

Изменено 7 Октября 2012 пользователем break

Страховид · 8 Октября 2012

Да, всё верно, Скрипт писал с использованием стандартых операций, основная из которых булен. Но представим такую ситуацию, нужно именно разрезать объект на несколько частей, а не отрезать кусочек, который просто пропадёт. Вот для этого мне и понадобилось написать этот скрипт, чтобы сэкономить время. Ведь тогда пришлось бы применять аж 4 операции из разных менюшек, вместо одного клика.

ЗЫ код глючноват

В чём проявляются глюки, ничего не замечал.

ЗЫЫ во вьюпорте беда с клиппингом, видно сетку с задних поверхностей

Это на моём скрине чтоли? просто видеокарта так работает, поставил ей упор на производительность, а не на качество. Ну а если выключить Wireframe on shaded, то всё нормально будет.

Деформировать объекты удобнее sculpt geometry tool'ом.

Смотря какой конечный результат нужен, если сглаженный, то скульптом конечно удобней. Ну а если грубая поверхность нужна, например для создания разколотого камня, или обвалившейся колонны. Скрипт деформер хорошо для этого подходит (кстатион не мой, я его вычитал у Цыпцына). Пользоваться им очень удобно. Выделить вертексы на сетке на плоскости и применять скрипт до нужного результата.

Вот совсем уже окончательный вариант, убрал всё лишнее и ужал как мог.

window -t "Strahovid_CUT" CUT_WINDOW;

columnLayout;

gridLayout -numberOfColumns 3 -cellWidthHeight 50 25;

button -l "DEFORM" -w 64 -c "def";

button -l "CUT" -w 64 -c "cut";

button -l "Undo" -w 64 -c "Undo;";

showWindow CUT_WINDOW;

global proc cut()

{

string $o1[] = `ls -sl`; //создаём переменную

string $ob1 = $o1[0]; //раскладываем по индексам, последовательность выделения

string $ob2 = $o1[1];

string $o2[] = `duplicate $o1`; //дублируем переменную $o1, заносим результат в другую переменную

string $ob3 = $o2[0];

string $ob4 = $o2[1];

polyNormal $ob3; //делаем реверс нормалей полученного объекта (плоскости)

string $rez1[] = `polyBoolOp -op 3 $ob1 $ob2`; //применяем булеан, заносим результаты в переменные

string $rez2[] = `polyBoolOp -op 3 $ob3 $ob4`;

xform -cp $rez1 $rez2; //центрируем пивоты у полученных объектов

}

global proc def()

{

string $list[] = `ls -sl -fl`;

string $item;

for($item in $list)

{

move -r (rand(-0.1,0.1)) (rand(-0.1,0.1)) (rand(-0.1,0.1)) $item;

}

Изменено 8 Октября 2012 пользователем Страховид

Страховид · 8 Октября 2012

Всем привет. Это снова я.

Я наверное уже достал вас своими простенькими скриптами, но когда нибудь я начну писать и более сложные коды. А пока очередное окно, как говорится, нет предела совершенству

Сделал всё таки возможность настройки скрипта деформера:

window -t "Страховид" GEN_WINDOW;

columnLayout;

columnLayout -cat "both" 5 -rs 10 -cw 400;

text -label "Скрипт Деформер";

separator -height 5 -style "in";

setParent..;

floatSliderGrp -l "Смещение по X" -field 1 -value 0.1 -min 0 -max 1 -s 0.01 X;

floatSliderGrp -l "Смещение по Y" -field 1 -value 0.1 -min 0 -max 1 -s 0.01 Y;

floatSliderGrp -l "Смещение по Z" -field 1 -value 0.1 -min 0 -max 1 -s 0.01 Z;

columnLayout -cat "both" 5 -rs 10 -cw 400;

button -l "Применить Девормер" -c "def";

separator -height 5 -style "in";

text -label "Скрипт CUT";

separator -height 5 -style "in";

button -l "Разрезать" -c "cut";

button -l "Отменить" -c "Undo";

showWindow GEN_WINDOW;

global proc def()

{

string $list[] = `ls -sl -fl`;

string $item;

float $mX = `floatSliderGrp -q -v X`;

float $mY = `floatSliderGrp -q -v Y`;

float $mZ = `floatSliderGrp -q -v Z`;

for($item in $list)

{

move -r (rand(-$mX,$mX)) (rand(-$mY,$mY)) (rand(-$mZ,$mZ)) $item;

}

global proc cut()

{

string $o1[] = `ls -sl`;

string $ob1 = $o1[0];

string $ob2 = $o1[1];

string $o2[] = `duplicate $o1`;

string $o5[] = `duplicate $ob1`;

string $ob3 = $o2[0];

string $ob4 = $o2[1];

polyNormal $ob3;

string $rez1[] = `polyBoolOp -op 3 $ob1 $ob2`;

string $rez2[] = `polyBoolOp -op 3 $ob3 $ob4`;

xform -cp $rez1 $rez2 $o5;

select $o5;

}

mwesten1 · 8 Октября 2012

Ребят у меня такой вопрос по поводу трейна. Я вот создал себе шпаргалку на новый терейн:

http://i39.fastpic.r...fb476836f01.jpg

Потом быстренько поделил плоскость на контуры шпаргалки и затекстурировал. Для анврапа использовал create UV's -> Automatic mapping и там поездил текстурой туда сюда.

http://i39.fastpic.r...4c7a8c43a6d.jpg

При этом я просто выделил полигоны дороги и наложил туда текстуру асфальта, сам меш не делил.

Отсюда вопрос: теперь можно сделать аналог максу Render to texture чтобы срендерил мне дифузку, а потом разделить меш на дорогу и на сам терейн, затекстурировать его, сложить обратно и экспортировать? Сохранит ли мая с моим способом UV координаты и поставит текстурку на нужноe место?

Или надо дорогу делать отдельно и терейн отдельно, потом их текстурировать, рендерить текстурку, соединять и экспортировать?

Вы с такими успехами долго на форуме не пробудете. Учите русский язык.

Пункт 2.5.

ColR_iT

Изменено 8 Октября 2012 пользователем ColR_iT

Страховид · 9 Октября 2012

Приветствую, шарил сегодня по интернету, наткнулся на крайне интересный набор скриптов - LayoutTools.

Из особенностей можно отметить удачно реализованную возможность создания каталога моделей, а также набор скриптов по настройке интерфейса. Там ещё что-то, но пока не вникал. В комплекте идёт хэлп (на английском) и видеоролики.

Официальный сайт - http://area.autodesk.com/blogs/stevenr/layouttools

Внимание! Эту тулзу можно скачать без регистрации (вроде-бы) и она абсолютно безплатна. А вообще, если с того сайта ещё что-то скачивать, то регистрация обязательна, но в то-же время не требует подтверждения мэйла. В общем, смотрите сами.

lychagin0 · 11 Октября 2012

Добрый день, решил сделать модель нпс, прискинил меш к костям, экспортирую в object всё нормально, прогнал через сдк, вставил в игру посмотрел недостатки поправил развесовку костей, экспорт в object вылет: приложение обратилось не по тому адресу. Т.е. не правленную модель экспортит, а чуть подправлю развесовку нет. Подскажите что может быть. Заранее спасибо.

maks 1984 · 15 Октября 2012

Кто знает как это лечить. Переустановка СДК и Майи не помогает.

can't open shaders.xr

can't open shaders_xrlc.xr

can't open gamemtl.xr

break · 15 Октября 2012

Страховид

посмотрел внимательнее - действительно прикольный скрипт.

немного поправил, в основном ui: http://pastebin.com/ueRahJLG

lychagin0

некорректно назначены веса, скорее всего.

в игру экспортировать незачем, достаточно проиграть анимацию в редакторе.

maks 1984

фс не может обнаружить файлы.

распакуй ресурсы игры в сдк или настрой xray_path.ltx плагина.

maks 1984 · 17 Октября 2012

Кто-нибудь сталкивался с такой вот проблемой.Возникает при попытке соеденения костей худа рук и худа оружия. // Error: Child and parent joint are the same

19Alone98 · 20 Октября 2012

Помогите, я скачал майу 2011, а там всего-лишь файл .ехе. Запускаю, всё работает. Но куда класть плагины? Есть вот bin в директории:

C:\Documents and Settings\Admin\Local Settings\Application Data\Xenocode\Sandbox\Maya\Fri 03_slash_19_slash_2010, 201003190014\2010.07.12T16.17\Virtual\DELETED\@PROGRAMFILES@\Autodesk\Maya2011\bin

И нашел плагины, но они в формате манифест.Вот пример:

MayaMuscle.mll_0x2585037abfab380d925506bf5f4d217d.2.manifest

Плагины находятся:

C:\Documents and Settings\Admin\Local Settings\Application Data\Xenocode\Sandbox\Maya\Fri 03_slash_19_slash_2010, 201003190014\2010.07.12T16.17\Virtual\SXS\Manifests

Изменено 20 Октября 2012 пользователем 19Alone98

KDit · 22 Октября 2012

Но куда класть плагины?

Плагины качаем тут,

1. Copy "C:\Program Files\X-Ray SDK\scripts_plugins\maya\scripts" to "C:\Documents and Settings\User\Мy Documents\maya\scripts"

2. Copy "C:\Program Files\X-Ray SDK\scripts_plugins\maya\ver-XXX" to "C:\Program Files\Autodesk\MayaXXX\bin\plugins"

3. Copy "C:\Program Files\X-Ray SDK\scripts_plugins\maya\" to "C:\Program Files\Autodesk\MayaXXX\bin\"

19Alone98 · 25 Октября 2012

Сделал как ты сказал, а майа их не видит. Видит файлы, которые типа находятся в папке"C:\Program Files\Autodesk\Maya2011\bin\plugins", но их там нет. Они находятся, как я уже говорил в формате манифест, в:

C:\Documents and Settings\Admin\Local Settings\Application Data\Xenocode\Sandbox\Maya\Fri 03_slash_19_slash_2010, 201003190014\2010.07.12T16.17\Virtual\SXS\Manifests\

Изменено 25 Октября 2012 пользователем 19Alone98

break · 25 Октября 2012

19Alone98

Ты скачал какую-то хрень - это раз; версия 2011 без сервис-паков весьма глюкава - это два. Не ленись приобрести нормальный дистрибутив Maya 2012 на рутрекере. Не знаешь, что такое рутрекер - спроси в гугле.

Проверь папку C:\Program Files\Autodesk\Maya\, её размер должен быть порядка полутора гигабайт. Если там ничего нет, проверь через Панель управления -> Программы и компоненты, есть ли Maya в списке установленных программ. Если есть, удали. Затем установи заново корректный дистр.

19Alone98 · 25 Октября 2012

А можно без скачивания?

Войти

Моделирование в Maya

95 голосов

1. Нужна ли отдельная тема "Анимирование в Maya"?

Рекомендуемые сообщения

ZVUKARb 3

Ссылка на комментарий

break 40

Ссылка на комментарий

Страховид 16

Ссылка на комментарий

Страховид 16

Ссылка на комментарий

Страховид 16

Ссылка на комментарий

Страховид 16

Ссылка на комментарий

mwesten1 1

Ссылка на комментарий

break 40

Ссылка на комментарий

Страховид 16

Ссылка на комментарий

Страховид 16

Ссылка на комментарий

mwesten1 1

Ссылка на комментарий

Страховид 16

Ссылка на комментарий

lychagin0 0

Ссылка на комментарий

maks 1984 0

Ссылка на комментарий

break 40

Ссылка на комментарий

maks 1984 0

Ссылка на комментарий

19Alone98 0

Ссылка на комментарий

KDit 3

Ссылка на комментарий

19Alone98 0

Ссылка на комментарий

break 40

Ссылка на комментарий

19Alone98 0

Ссылка на комментарий

Создайте аккаунт или авторизуйтесь, чтобы оставить комментарий

Создать аккаунт

Войти

Недавно просматривали 0 пользователей

AMK Склад